BSTR from C Dll to VB

Author: Dave
Date: 11.16.20 - 3:29pm

So lets say you have a C function prototype such as the following:

BSTR __stdcall vbcurl_string_escape(wchar_t* ws, int size)

How do you write your API declaration in VB6 to handle this? We all know VB6 deals with BSTRs this should be ok right?

Mmm not really. The Api declare mechanism was written to allow vb6 to interact with standard C dlls. So the runtime does all kinds of automagic translations to meet that expectation.

If your C dll is returning a SysAlloc* BSTR, technically you would need to write a tlb file to include in your VB6.

Ok..so what if you dont want to write and reference a tlb file because they are inconvenient? Can VB6 work with this BSTR anyway?

Now I know what your thinking and the answer is NO. If you try to declare the vb api def with an As String return type, you will get an double unicode string and a leaked BSTR that never gets free'd.

We can however screw with things a little bit and make it work.

Public Declare Function vbcurl_string_escape Lib "vblibcurl.dll" ( _
    ByVal strPtr As Long, _
    ByVal sz As Long _
) As Long

Function escape(ByVal buf As String) As String
    Dim tmp As Long, s As String
    tmp = vbcurl_string_escape(strPtr(buf), Len(buf))
    CopyMemory ByVal VarPtr(s), tmp, 4 'steal a ref to an existing BSTR so we now own it
    escape = s
End Function

If you look at the varptr(s) before it has been set to anything, it value at that address is 0. So VB6 knows it is not a active BSTR and does not need to free it.

This means there is no memory leak if we manually stuff it with a reference to an existing BSTR which no one else owns and no one else will free.

Another example:

'[entry(0x60000027), helpstring("Get supported protocols")]
'void _stdcall vbcurl_version_protocols(
'                [in] long ver,
'                [out] SAFEARRAY(BSTR)* ppsa);
Public Declare Sub vbcurl_version_protocols Lib "vblibcurl.dll" (ByVal hVerInfo As Long, ByRef ary() As Long)


Function libcurlProtocols() As String()
    Dim ptr() As Long, vd As Long, i As Long, s() As String, tmp As String
    
    vd = vbcurl_version_info(CURLVERSION_NOW)
    vbcurl_version_protocols vd, ptr
    
    If AryIsEmpty(ptr) Then Exit Function
    
    ReDim s(UBound(ptr))
    For i = 0 To UBound(ptr)
        CopyMemory ByVal VarPtr(tmp), ptr(i), 4 'steal a ref to an existing BSTR so we now own it
        s(i) = tmp
        'Debug.Print ptr(i) & " " & s(i)
    Next
    
    libcurlProtocols = s()
    
End Function

Comments: (1)

On 03.23.22 - 2:40pm Dave wrote:
this gave me some problems today see the zlib2 post

Leave Comment:

Name:

Email: (not shown)

Message: (Required)

Math Question: 91 + 89 = ? followed by the letter: E