UDT Tricks pt2

Author: Dave
Date: 09.12.16 - 7:52pm

In a previous article we talked about how the VB6 runtime includes a cool feature that allows it to serialize and deseralize complex UDT structures to disk. (Primer on UDTs here)

In memory a string or array element would be pointers...so you cant use copymemory to grab them and transfer them. By dumping them to disk, the data will be packed appropriately and can be reloaded at any time fully configured.

So I have always had a thought in the back of my mind..this is so cool, but it feels sloppy to have to use all these temp files if you wanted to transfer a udt. Is there a way to do it without the temp files? Could I redirect it to memory or a different type of file handle? A socket?

I played with it some this last weekend and came up with a solution using API hooks on ReadFile, WriteFile, CreateFileA, CloseHandle, and GetFileType. The hook lib is done in C, with VB6 hook implementations.

It might be a little heavy handed, but it was an experiment. Time will tell if it has any practical value or is just a novelty. It doesnt add that much code, but could impact stability.

Below is a sample: (full source here)

Private Type test
    signature As Long
    buf As String
    signature2 As Long
    v As Variant
End Type

Dim seralized() As Byte

Private Sub Command1_Click()
    Dim f As Long
    Dim udtTest As test
    With udtTest
        .signature = &H11223344
        .buf = "test string"
        .signature2 = &H99887766
        .v = Array(1, "blah!", 3.14)
    End With

    f = mSer.StartSeralize()
    Put f, , udtTest
    seralized() = mSer.EndSeralize()
    Text1 = HexDump(StrConv(seralized, vbUnicode, LANG_US))
End Sub

Private Sub Command2_Click()

    Dim f As Long
    Dim udtTest As test

    f = mSer.StartSeralize()
    mSer.SetReadBuffer seralized()
    Get f, , udtTest
    On Error Resume Next
    Dim tmp() As String
    push tmp, "Signature: " & Hex(udtTest.signature)
    push tmp, "Buf: " & udtTest.buf
    push tmp, "Signature2: " & Hex(udtTest.signature2)
    push tmp, "v: " & Join(udtTest.v, ", ")
    Text1 = Join(tmp, vbCrLf)
End Sub

Another implementation VB6 pipe-based UDT-serializing/deserializing InMemory by Schmidt was also pointed out to me. It has the added benefit of being lite weight with no external dependencies or hooking. Down side it does use fragmented logic with event call backs. (local copy)

It might not be obvious, but the reason we both wanted the Get/Put statements to be outside of the library code is because VB has restrictions about how UDTs can be passed as variants so its best to let the caller handle them in their own scope for flexibility.

Comments: (0)

Leave Comment:
Email: (not shown)
Message: (Required)
Math Question: 34 + 46 = ? followed by the letter: O 

About Me
More Blogs
Main Site
Posts: (All)
2024 ( 2 )
2023 ( 9 )
2022 ( 4 )
2021 ( 2 )
2020 ( 4 )
2019 ( 5 )
2018 ( 6 )
2017 ( 6 )
2016 (22)
     VB6 CDECL
     UDT Tricks pt2
     Remote Data Extraction
     Collection Extender
     VB6 FindResource
     DirList Single Click
     Reset CheckPoint VPN Policy
     VB6 BSTR Oddities Explained
     SafeArrays in C
     BSTR and Variant in C++
     Property let optional args
     Misc Libs
     Enum Named Pipes
     Vb6 Collection in C++
     VB6 Overloaded Methods
     VB6 Syncronous Socket
     Simple IPC
     VB6 Auto Resize Form Elements
     Mach3 Automation
     Exit For in While
2015 ( 15 )
2014 ( 25 )
2013 ( 4 )
2012 ( 10 )
2011 ( 7 )
2010 ( 11 )
2009 ( 3 )